cmake_minimum_required(VERSION 3.18)
project(
  conflict-set
  VERSION 0.0.1
  DESCRIPTION "A data structure for detecting mvcc read-write conflicts in a keyspace of lexicographically-ordered byte sequences."
  LANGUAGES C CXX)
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)

add_compile_options(-fdata-sections -ffunction-sections -fPIE)
if(APPLE)
  add_link_options(-Wl,-dead_strip)
else()
  add_link_options(-Wl,--gc-sections)
endif()

add_library(conflict_set SHARED ConflictSet.cpp ConflictSet.h)
target_compile_options(conflict_set PRIVATE -fno-exceptions -fvisibility=hidden)
target_link_options(conflict_set PRIVATE -nodefaultlibs -lc -fvisibility=hidden)
if (CMAKE_BUILD_TYPE STREQUAL Release)
  add_custom_command(TARGET conflict_set POST_BUILD COMMAND ${CMAKE_STRIP} -x $<TARGET_FILE:conflict_set>)
endif()

if (NOT APPLE)
  target_link_options(conflict_set PRIVATE "LINKER:--version-script=${CMAKE_CURRENT_SOURCE_DIR}/linker.map")
endif()

include(CTest)

# unit test

add_executable(conflict_set_test ConflictSet.cpp ConflictSet.h)
target_compile_definitions(conflict_set_test PRIVATE ENABLE_TESTS)
# keep asserts for test
target_compile_options(conflict_set_test PRIVATE -UNDEBUG)
# Only emit compile warnings for test
target_compile_options(conflict_set_test PRIVATE -Wall -Wextra -Wpedantic -Wunreachable-code)
target_compile_options(conflict_set_test PRIVATE -fsanitize=address,undefined)
target_link_options(conflict_set_test PRIVATE -fsanitize=address,undefined)
add_test(NAME conflict_set_test COMMAND conflict_set_test)

# api smoke tests

# c99
add_executable(conflict_set_c_api_test conflict_set_c_api_test.c ConflictSet.h)
target_link_libraries(conflict_set_c_api_test PRIVATE conflict_set)
target_compile_options(conflict_set_c_api_test PRIVATE -UNDEBUG)
set_property(TARGET conflict_set_c_api_test PROPERTY C_STANDARD 99)
add_test(NAME conflict_set_c_api_test COMMAND conflict_set_c_api_test)
target_compile_options(conflict_set_c_api_test PRIVATE -Wall -Wextra -Wpedantic -Wunreachable-code -Werror)

# c++98
add_executable(conflict_set_cxx_api_test conflict_set_cxx_api_test.cpp ConflictSet.h)
target_link_libraries(conflict_set_cxx_api_test PRIVATE conflict_set)
target_compile_options(conflict_set_cxx_api_test PRIVATE -UNDEBUG)
set_property(TARGET conflict_set_cxx_api_test PROPERTY CXX_STANDARD 98)
add_test(NAME conflict_set_cxx_api_test COMMAND conflict_set_cxx_api_test)
target_compile_options(conflict_set_cxx_api_test PRIVATE -Wall -Wextra -Wpedantic -Wunreachable-code -Werror)

# fuzz test
set(FUZZ_FLAGS "-fsanitize=fuzzer-no-link,address,undefined")
include(CheckCXXCompilerFlag)
set(CMAKE_REQUIRED_LINK_OPTIONS ${FUZZ_FLAGS})
check_cxx_compiler_flag(${FUZZ_FLAGS} HAS_LIB_FUZZER)

if (HAS_LIB_FUZZER)
  add_executable(conflict_set_fuzz_test ConflictSet.cpp ConflictSet.h)
  target_compile_definitions(conflict_set_fuzz_test PRIVATE ENABLE_FUZZ)
  # keep asserts for test
  target_compile_options(conflict_set_fuzz_test PRIVATE -UNDEBUG)
  target_compile_options(conflict_set_fuzz_test PRIVATE -Wall -Wextra -Wpedantic -Wunreachable-code)
  target_compile_options(conflict_set_fuzz_test PRIVATE ${FUZZ_FLAGS})
  target_link_options(conflict_set_fuzz_test PRIVATE ${FUZZ_FLAGS} -fsanitize=fuzzer)
endif()