cmake_minimum_required(VERSION 3.18)
project(
  conflict-set
  VERSION 0.0.1
  DESCRIPTION "A data structure for detecting mvcc read-write conflicts in a keyspace of lexicographically-ordered byte sequences."
  LANGUAGES C CXX)
set(CMAKE_CXX_STANDARD 20)

add_compile_options(-fdata-sections -ffunction-sections -fPIE)
if(APPLE)
  add_link_options(-Wl,-dead_strip)
else()
  add_link_options(-Wl,--gc-sections)
endif()

include(CheckIncludeFileCXX)
include(CMakePushCheckState)

cmake_push_check_state()
# Fall back to non-simd implementations if avx isn't available
list(APPEND CMAKE_REQUIRED_FLAGS -mavx)
check_include_file_cxx("immintrin.h" HAS_AVX)
if(HAS_AVX)
  add_compile_options(-mavx)
  add_compile_definitions(HAS_AVX)
endif()
cmake_pop_check_state()

check_include_file_cxx("arm_neon.h" HAS_ARM_NEON)
if (HAS_ARM_NEON)
  add_compile_definitions(HAS_ARM_NEON)
endif()

add_library(conflict_set SHARED ConflictSet.cpp)
target_include_directories(conflict_set PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/include)
target_compile_options(conflict_set PRIVATE -fno-exceptions -fvisibility=hidden)
if (CMAKE_BUILD_TYPE STREQUAL Release)
  target_link_options(conflict_set PRIVATE -nodefaultlibs -lc -fvisibility=hidden)
  add_custom_command(TARGET conflict_set POST_BUILD COMMAND ${CMAKE_STRIP} -x $<TARGET_FILE:conflict_set>)
endif()

if (NOT APPLE)
  target_link_options(conflict_set PRIVATE "LINKER:--version-script=${CMAKE_CURRENT_SOURCE_DIR}/linker.map")
endif()

set(TEST_FLAGS -Wall -Wextra -Wpedantic -Wunreachable-code -UNDEBUG)

include(CTest)

add_executable(conflict_set_main ConflictSet.cpp)
target_include_directories(conflict_set_main PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/include)
target_compile_definitions(conflict_set_main PRIVATE ENABLE_MAIN)

# libfuzzer target, to generate/manage corpus
set(FUZZ_FLAGS "-fsanitize=fuzzer-no-link,address,undefined")
include(CheckCXXCompilerFlag)
cmake_push_check_state()
set(CMAKE_REQUIRED_LINK_OPTIONS ${FUZZ_FLAGS})
check_cxx_compiler_flag(${FUZZ_FLAGS} HAS_LIB_FUZZER)
cmake_pop_check_state()

if (HAS_LIB_FUZZER)
  add_executable(conflict_set_fuzz_test ConflictSet.cpp)
  target_include_directories(conflict_set_fuzz_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/include)
  target_compile_definitions(conflict_set_fuzz_test PRIVATE ENABLE_FUZZ)
  target_compile_options(conflict_set_fuzz_test PRIVATE ${TEST_FLAGS})
  target_compile_options(conflict_set_fuzz_test PRIVATE ${FUZZ_FLAGS})
  target_link_options(conflict_set_fuzz_test PRIVATE ${FUZZ_FLAGS} -fsanitize=fuzzer)
endif()

# corpus tests

file(GLOB CORPUS_TESTS ${CMAKE_SOURCE_DIR}/corpus/*)

add_executable(conflict_set_test_driver ConflictSet.cpp TestDriver.cpp)
target_compile_options(conflict_set_test_driver PRIVATE ${TEST_FLAGS})
target_compile_definitions(conflict_set_test_driver PRIVATE ENABLE_FUZZ)
target_include_directories(conflict_set_test_driver PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/include)
foreach(TEST ${CORPUS_TESTS})
  get_filename_component(hash ${TEST} NAME)
  add_test(NAME conflict_set_corpus_${hash} COMMAND conflict_set_test_driver ${TEST})
endforeach()

# api smoke tests

# c90
add_executable(conflict_set_c_api_test conflict_set_c_api_test.c)
target_compile_options(conflict_set_c_api_test PRIVATE ${TEST_FLAGS})
target_link_libraries(conflict_set_c_api_test PRIVATE conflict_set)
set_property(TARGET conflict_set_c_api_test PROPERTY C_STANDARD 90)
set_property(TARGET conflict_set_c_api_test PROPERTY C_STANDARD_REQUIRED ON)
add_test(NAME conflict_set_c_api_test COMMAND conflict_set_c_api_test)

# c++98
add_executable(conflict_set_cxx_api_test conflict_set_cxx_api_test.cpp)
target_compile_options(conflict_set_cxx_api_test PRIVATE ${TEST_FLAGS})
target_link_libraries(conflict_set_cxx_api_test PRIVATE conflict_set)
set_property(TARGET conflict_set_c_api_test PROPERTY CXX_STANDARD 98)
set_property(TARGET conflict_set_c_api_test PROPERTY CXX_STANDARD_REQUIRED ON)
add_test(NAME conflict_set_cxx_api_test COMMAND conflict_set_cxx_api_test)